经验首页 前端设计 程序设计 Java相关 移动开发 数据库/运维 软件/图像 大数据/云计算 其他经验
当前位置：技术经验 » 程序设计 » 游戏设计 » 查看文章
DirectX11 With Windows SDK--27 计算着色器：双调排序
来源：cnblogs　　作者：X_Jun　　时间：2019/2/19 9:13:39　　对本文有异议

前言

上一章我们用一个比较简单的例子来尝试使用计算着色器，但是在看这一章内容之前，你还需要了解一些缓冲区的创建和使用方式：

章节
深入理解与使用缓冲区资源

这一章我们继续用一个计算着色器的应用实例作为切入点，进一步了解相关知识。

DirectX11 With Windows SDK完整目录

Github项目源码

欢迎加入QQ群: 727623616 可以一起探讨DX11，以及有什么问题也可以在这里汇报。

线程标识符

对于线程组(大小(ThreadDimX, ThreadDimY, ThreadDimZ))中的每一个线程，它们都有一个唯一的线程ID值。我们可以使用系统值SV_GroupThreadID来取得，它的索引范围为(0, 0, 0)到(ThreadDimX - 1, ThreadDimY - 1, ThreadDimZ - 1)。

而对于整个线程组来说，由于线程组集合也是在3D空间中排布，它们也有一个唯一的线程组ID值。我们可以使用系统值SV_GroupID来取得，线程组的索引范围取决于调用ID3D11DeviceContext::Dispatch时提供的线程组(大小(GroupDimX, GroupDimY, GroupDimZ))，范围为(0, 0, 0)到(GroupDimX - 1, GroupDimY - 1, GroupDimZ - 1)。

紧接着就是系统值SV_GroupIndex，它是单个线程组内的线程三维索引的一维展开。若已知线程组的大小为(ThreadDimX, ThreadDimY, ThreadDimZ)，则可以确定SV_GroupIndex与SV_GroupThreadID满足下面关系：

  1. SV_GroupIndex = SV_GroupThreadID.z * ThreadDimX * ThreadDimY + SV_GroupThreadID.y * ThreadDimX + SV_GroupThreadID.x;

最后就是系统值SV_DispatchThreadID，线程组中的每一个线程在ID3D11DeviceContext::Dispatch提供的线程组集合中都有其唯一的线程ID值。若已知线程组的大小为 (ThreadDimX, ThreadDimY, ThreadDimZ)，则可以确定SV_DispatchThreadID，SV_GroupThreadID和SV_GroupID满足以下关系：

  1. SV_DispatchThreadID.xyz = SV_GroupID.xyz * float3(ThreadDimX, ThreadDimY, ThreadDimZ) + SV_GroupThreadID.xyz;

共享内存和线程同步

在一个线程组内，允许设置一片共享内存区域，使得当前线程组内的所有线程都可以访问当前的共享内存。一旦设置，那么每个线程都会各自配备一份共享内存。共享内存的访问速度非常快，就像寄存器访问CPU缓存那样。

共享内存的声明方式如下：

  1. groupshared float4 gCache[256];

对于每个线程组来说，它所允许分配的总空间最大为32kb(即8192个标量，或2048个向量)。内部线程通常应该使用SV_ThreadGroupID来写入共享内存，这样以保证每个线程不会出现重复写入操作，而读取共享内存一般是线程安全的。

分配太多的共享内存会导致性能问题。假如一个多处理器支持32kb的共享内存，然后你的计算着色器需要20kb的共享内存，这意味着一个多处理器只适合处理一个线程组，因为剩余的共享内存不足以给新的线程组运行，这也会限制GPU的并行运算，当该线程组因为某些原因需要等待，会导致当前的多处理器处于闲置状态。因此保证一个多处理器至少能够处理两个或以上的线程组(比如每个线程组分配16kb以下的共享内存)，以尽可能减少该多处理器的闲置时间。

现在来考虑下面的代码：

  1. Texture2D gInput : register(t0);
  2. RWTexture2D<float4> gOutput : register(u0);
  4. groupshared float4 gCache[256];
  6. [numthreads(256, 1, 1)]
  7. void CS(uint3 GTid : SV_GroupThreadID,
  8.     uint3 DTid : SV_DispatchThreadID)
  9. {
  10.     // 将纹理像素值缓存到共享内存
  11.     gCache[GTid.x] = gInput[DTid.xy];
  12.     
  13.     // 取出共享内存的值进行计算
  14.     
  15.     // 注意！！相邻的两个线程可能没有完成对纹理的采样
  16.     // 以及存储到共享内存的操作
  17.     float left = gCache[GTid.x - 1];
  18.     float right = gCache[GTid.x + 1];
  19.     
  20.     // ...
  21. }

因为多个线程同时运行，同一时间各个线程当前执行的指令有所偏差，有的线程可能已经完成了共享内存的赋值操作，有的线程可能还在进行纹理采样操作。如果当前线程正在读取相邻的共享内存片段，结果将是未定义的。为了解决这个问题，我们必须在读取共享内存之前让当前线程等待线程组内其它的所有线程完成写入操作。这里我们可以使用GroupMemoryBarrierWithGroupSync函数：

  1. Texture2D gInput : register(t0);
  2. RWTexture2D<float4> gOutput : register(u0);
  4. groupshared float4 gCache[256];
  6. [numthreads(256, 1, 1)]
  7. void CS(uint3 GTid : SV_GroupThreadID,
  8.     uint3 DTid : SV_DispatchThreadID)
  9. {
  10.     // 将纹理像素值缓存到共享内存
  11.     gCache[GTid.x] = gInput[DTid.xy];
  12.     
  13.     // 等待所有线程完成写入
  14.     GroupMemoryBarrierWithGroupSync();
  15.     
  16.     // 现在读取操作是线程安全的，可以开始进行计算
  17.     float left = gCache[GTid.x - 1];
  18.     float right = gCache[GTid.x + 1];
  19.     
  20.     // ...
  21. }

双调排序

双调序列

所谓双调序列(Bitonic Sequence)，是指由一个非严格递增序列X(允许相邻两个数相等)和非严格递减序列Y构成的序列，比如序列\((5, 3, 2, 1, 4, 6, 6, 12)\)。

定义：一个序列\(a_1 , a_2, ..., a_n\)是双调序列，需要满足下面条件：

  1. 存在一个\(a_k(1 <= k <= n)\)，使得\(a_1 >= ... >= a_k <= ... <= a_n\)成立，或者\(a_1 <= ... <= a_k >= ... >= a_n\)成立；
  2. 序列循环移位后仍能够满足条件(1)

Batcher归并网络

Batcher归并网络是由一系列Batcher比较器组成的，Batcher比较器是指在两个输入端给定输入值x和y，再在两个输出端输出最大值\(max(x, y)\)和最小值\(min(x, y)\)。

双调归并网络

双调归并网络是基于Batch定理而构建的。该定理是说将任意一个长为2n的双调序列分为等长的两半X和Y，将X中的元素与Y中的元素按原序比较，即\(a_i\)与\(a_{i+n}(i <= n)\)比较，将较大者放入MAX序列，较小者放入MIN序列。则得到的MAX序列和MIN序列仍然是双调序列，并且MAX序列中的任意一个元素不小于MIN序列中的任意一个元素。

根据这个原理，我们可以将一个n元素的双调序列通过上述方式进行比较操作来得到一个MAX序列和一个MIN序列，然后对这两个序列进行递归处理，直到序列不可再分割为止。最终归并得到的为一个有序序列。

这里我们用一张图来描述双调排序的全过程：

其中箭头方向指的是两个数交换后，箭头段的数为较大值，圆点段的数为较小值。

我们可以总结出如下规律：

  1. 每一趟排序结束会产生连续的双调序列，除了最后一趟排序会产生我们所需要的单调序列
  2. 对于2^k个元素的任意序列，需要进行k趟排序才能产生单调序列
  3. 对于由\(2^{k-1}\)个元素的单调递增序列和\(2^{k-1}\)个元素的单调递减序列组成的双调序列，需要进行k趟交换才能产生2^k个元素的单调递增序列
  4. 在第n趟排序中的第m趟交换，若两个比较数中较小的索引值为i，那么与之进行交换的数索引为\(i+2^{n-m}\)

双调排序的空间复杂度为\(O(n)\)，时间复杂度为\(O(n{(lg(n))}^2)\)，看起来比\(O(nlg(n))\)系列的排序算法慢上一截，但是得益于GPU的并行计算，可以看作同一时间内有n个线程在运行，使得最终的时间复杂度可以降为\(O({(lg(n))}^2)\)，效率又上了一个档次。

需要注意的是，双调排序要求排序元素的数目为\(2^k, (k>=1)\)，如果元素个数为\(2^k < n < 2^{k+1}\)，则需要填充数据到\(2^{k+1}\)个。若需要进行升序排序，则需要填充足够的最大值；若需要进行降序排序，则需要填充足够的最小值。

排序核心代码实现

本HLSL实现参考了directx-sdk-samples，虽然里面的实现看起来比较简洁，但是理解它的算法实现费了我不少的时间。个人以自己能够理解的形式对它的实现进行了修改，因此这里以我这边的实现版本来讲解。

首先是排序需要用到的资源和常量缓冲区，定义在BitonicSort.hlsli：

  1. // BitonicSort.hlsli
  2. Buffer<uint> gInput : register(t0);
  3. RWBuffer<uint> gData : register(u0);
  5. cbuffer CB : register(b0)
  6. {
  7.     uint gLevel;        // 2^需要排序趟数
  8.     uint gDescendMask;  // 下降序列掩码
  9.     uint gMatrixWidth;  // 矩阵宽度(要求宽度>=高度且都为2的倍数)
  10.     uint gMatrixHeight; // 矩阵高度
  11. }

然后是核心的排序算法：

  1. // BitonicSort_CS.hlsl
  2. #include "BitonicSort.hlsli"
  4. #define BITONIC_BLOCK_SIZE 512
  6. groupshared uint shared_data[BITONIC_BLOCK_SIZE];
  8. [numthreads(BITONIC_BLOCK_SIZE, 1, 1)]
  9. void CS(uint3 Gid : SV_GroupID,
  10.     uint3 DTid : SV_DispatchThreadID,
  11.     uint3 GTid : SV_GroupThreadID,
  12.     uint GI : SV_GroupIndex)
  13. {
  14.     // 写入共享数据
  15.     shared_data[GI] = gData[DTid.x];
  16.     GroupMemoryBarrierWithGroupSync();
  17.     
  18.     // 进行排序
  19.     for (uint j = gLevel >> 1; j > 0; j >>= 1)
  20.     {
  21.         uint smallerIndex = GI & ~j;
  22.         uint largerIndex = GI | j;
  23.         bool isDescending = (bool) (gDescendMask & DTid.x);
  24.         bool isSmallerIndex = (GI == smallerIndex);
  25.         uint result = ((shared_data[smallerIndex] <= shared_data[largerIndex]) == (isDescending == isSmallerIndex)) ?
  26.             shared_data[largerIndex] : shared_data[smallerIndex];
  27.         GroupMemoryBarrierWithGroupSync();
  29.         shared_data[GI] = result;
  30.         GroupMemoryBarrierWithGroupSync();
  31.     }
  32.     
  33.     // 保存结果
  34.     gData[DTid.x] = shared_data[GI];
  35. }

可以看到，我们实际上可以将递归过程转化成迭代来实现。

现在我们先从核心排序算法讲起，由于收到线程组的线程数目、共享内存大小限制，这里定义一个线程组包含512个线程，即一个线程组最大允许排序的元素数目为512。这里共享内存的作用在这里是临时缓存中间排序的结果。

首先，我们需要将数据写入共享内存中：

  1. // 写入共享数据
  2. shared_data[GI] = gData[DTid.x];
  3. GroupMemoryBarrierWithGroupSync();

接着就是要开始递归排序的过程，其中gLevel的含义为单个双调序列的长度，它也说明了需要对该序列进行\(lg(gLevel)\)趟递归交换。

在一个线程中，我们仅知道该线程对应的元素，但现在我们还需要做两件事情：

  1. 找到需要与该线程对应元素进行Batcher比较的另一个元素
  2. 判断当前线程对应元素与另一个待比较元素相比，是较小索引还是较大索引

这里用到了位运算的魔法。先举个例子，当前j为4，则待比较两个元素的索引分别为2和6，这两个索引值的区别在于索引2(二进制010)和索引6(二进制110)，前者二进制第三位为0，后者二进制第三位为1.

但只要我们知道上述其中的一个索引，就可以求出另一个索引。较小索引值的索引可以通过屏蔽二进制的第三位得到，而较大索引值的索引可以通过按位或运算使得第三位为1来得到：

  1. uint smallerIndex = GI & ~j;
  2. uint largerIndex = GI | j;
  3. bool isSmallerIndex = (GI == smallerIndex);

然后就是判断当前元素是位于当前趟排序完成后的递增序列还是递减序列，比如序列\((4, 6, 4, 3, 5, 7, 2, 1)\)，现在要进行第二趟排序，那么前后4个数将分别生成递增序列和递减序列，我们可以设置gDescendMask的值为4(二进制100)，这样二进制索引范围在100到111的值(对应十进制4-7)处在递减序列，如果这个双调序列长度为16，那么索引4-7和12-15的两段序列都可以通过gDescendMask来判断出处在递减序列：

  1. bool isDescending = (bool) (gDescendMask & DTid.x);

最后就是要确定当前线程对应的共享内存元素需要得到较小值，还是较大值了。这里又以一个双调序列\((2, 5, 7, 4)\)为例，待比较的两个元素为5和4，当前趟排序会将它变为单调递增序列，即所处的序列为递增序列，当前线程对应的元素为5，shared_data[smallerIndex] <= shared_data[largerIndex]的比较结果为>，那么它将拿到(较小值)较大索引的值。经过第一趟交换后将变成\((2, 4, 7, 5)\)，第二趟交换就不讨论了。

根据对元素所处序列、元素当前索引和比较结果的讨论，可以产生出八种情况：

所处序列 当前索引 比较结果 取值结果
递减 小索引 <= (较大值)较大索引的值
递减 大索引 <= (较小值)较大索引的值
递增 小索引 <= (较小值)较小索引的值
递增 大索引 <= (较大值)较小索引的值
递减 小索引 > (较大值)较小索引的值
递减 大索引 > (较小值)较小索引的值
递增 小索引 > (较小值)较大索引的值
递增 大索引 > (较大值)较大索引的值

显然现有的变量判断较大/较小索引值比判断较大值/较小值容易得多。上述结果表可以整理成下面的代码：

  1. uint result = ((shared_data[smallerIndex] <= shared_data[largerIndex]) == (isDescending == isSmallerIndex)) ?
  2.     shared_data[largerIndex] : shared_data[smallerIndex];
  3. GroupMemoryBarrierWithGroupSync();
  5. shared_data[GI] = result;
  6. GroupMemoryBarrierWithGroupSync();

在C++中，现在有如下资源和着色器：

  1. ComPtr<ID3D11Buffer> mConstantBuffer;           // 常量缓冲区
  2. ComPtr<ID3D11Buffer> mTypedBuffer1;             // 有类型缓冲区1
  3. ComPtr<ID3D11Buffer> mTypedBuffer2;             // 有类型缓冲区2
  5. ComPtr<ID3D11UnorderedAccessView> mDataUAV1;    // 有类型缓冲区1对应的无序访问视图
  6. ComPtr<ID3D11UnorderedAccessView> mDataUAV2;    // 有类型缓冲区2对应的无序访问视图
  7. ComPtr<ID3D11ShaderResourceView> mDataSRV1;     // 有类型缓冲区1对应的着色器资源视图
  8. ComPtr<ID3D11ShaderResourceView> mDataSRV2;     // 有类型缓冲区2对应的着色器资源视图

然后就是对512个元素进行排序的部分代码(size为2的次幂)：

  1. void GameApp::SetConstants(UINT level, UINT descendMask, UINT matrixWidth, UINT matrixHeight);
  3. //
  4. // GameApp::GPUSort
  5. //
  7. md3dImmediateContext->CSSetShader(mBitonicSort_CS.Get(), nullptr, 0);
  8. md3dImmediateContext->CSSetUnorderedAccessViews(0, 1, mDataUAV1.GetAddressOf(), nullptr);
  10. // 按行数据进行排序，先排序level <= BLOCK_SIZE 的所有情况
  11. for (UINT level = 2; level <= size && level <= BITONIC_BLOCK_SIZE; level *= 2)
  12. {
  13.     SetConstants(level, level, 0, 0);
  14.     md3dImmediateContext->Dispatch((size + BITONIC_BLOCK_SIZE - 1) / BITONIC_BLOCK_SIZE, 1, 1);
  15. }

给更多的数据排序

上述代码允许我们对元素个数为2到512的序列进行排序，但缓冲区的元素数目必须为2的次幂。由于在CS4.0中，一个线程组最多允许一个线程组包含768个线程，这意味着双调排序仅允许在一个线程组中对最多512个元素进行排序。

这里我们看一个例子，假如有一个16元素的序列，然而线程组仅允许包含最多4个线程，那我们将其放置在一个4x4的矩阵内：

然后对矩阵转置：

可以看到，通过转置后，列数据变换到行数据的位置，这样我们就可以进行跨度更大的交换操作了。处理完大跨度的交换后，我们再转置回来，处理行数据即可。

现在假定我们已经对行数据排完序，下图演示了剩余的排序过程：

但是在线程组允许最大线程数为4的情况下，通过二维矩阵最多也只能排序16个数。。。。也许可以考虑三维矩阵转置法，这样就可以排序64个数了哈哈哈。。。

不过还有一个情况我们要考虑，就是元素数目不为(2x2)的倍数，无法构成一个方阵，但我们也可以把它变成对两个方阵转置。这时矩阵的宽是高的两倍：

由于元素个数为32，它的最大索引跨度为16，转置后的索引跨度为2，不会越界到另一个方阵进行比较。但是当gLevel到32时，此时进行的是单调排序，gDescendMask也必须设为最大值32(而不是4)，避免产生双调序列。

负责转置的着色器实现如下：

  1. // MatrixTranspose_CS.hlsl
  2. #include "BitonicSort.hlsli"
  4. #define TRANSPOSE_BLOCK_SIZE 16
  6. groupshared uint shared_data[TRANSPOSE_BLOCK_SIZE * TRANSPOSE_BLOCK_SIZE];
  8. [numthreads(TRANSPOSE_BLOCK_SIZE, TRANSPOSE_BLOCK_SIZE, 1)]
  9. void CS(uint3 Gid : SV_GroupID,
  10.     uint3 DTid : SV_DispatchThreadID,
  11.     uint3 GTid : SV_GroupThreadID,
  12.     uint GI : SV_GroupIndex)
  13. {
  14.     uint index = DTid.y * gMatrixWidth + DTid.x;
  15.     shared_data[GI] = gInput[index];
  16.     GroupMemoryBarrierWithGroupSync();
  17.     
  18.     uint2 outPos = DTid.yx % gMatrixHeight + DTid.xy / gMatrixHeight * gMatrixHeight;
  19.     gData[outPos.y * gMatrixWidth + outPos.x] = shared_data[GI];
  20. }

最后是GPU排序用的函数：

  1. void GameApp::GPUSort()
  2. {
  3.     UINT size = (UINT)mRandomNums.size();
  5.     md3dImmediateContext->CSSetShader(mBitonicSort_CS.Get(), nullptr, 0);
  6.     md3dImmediateContext->CSSetUnorderedAccessViews(0, 1, mDataUAV1.GetAddressOf(), nullptr);
  8.     // 按行数据进行排序，先排序level <= BLOCK_SIZE 的所有情况
  9.     for (UINT level = 2; level <= size && level <= BITONIC_BLOCK_SIZE; level *= 2)
  10.     {
  11.         SetConstants(level, level, 0, 0);
  12.         md3dImmediateContext->Dispatch((size + BITONIC_BLOCK_SIZE - 1) / BITONIC_BLOCK_SIZE, 1, 1);
  13.     }
  14.     
  15.     // 计算相近的矩阵宽高(宽>=高且需要都为2的次幂)
  16.     UINT matrixWidth = 2, matrixHeight = 2;
  17.     while (matrixWidth * matrixWidth < size)
  18.     {
  19.         matrixWidth *= 2;
  20.     }
  21.     matrixHeight = size / matrixWidth;
  23.     // 排序level > BLOCK_SIZE 的所有情况
  24.     ComPtr<ID3D11ShaderResourceView> pNullSRV;
  25.     for (UINT level = BITONIC_BLOCK_SIZE * 2; level <= size; level *= 2)
  26.     {
  27.         // 如果达到最高等级，则为全递增序列
  28.         if (level == size)
  29.         {
  30.             SetConstants(level / matrixWidth, level, matrixWidth, matrixHeight);
  31.         }
  32.         else
  33.         {
  34.             SetConstants(level / matrixWidth, level / matrixWidth, matrixWidth, matrixHeight);
  35.         }
  36.         // 先进行转置，并把数据输出到Buffer2
  37.         md3dImmediateContext->CSSetShader(mMatrixTranspose_CS.Get(), nullptr, 0);
  38.         md3dImmediateContext->CSSetShaderResources(0, 1, pNullSRV.GetAddressOf());
  39.         md3dImmediateContext->CSSetUnorderedAccessViews(0, 1, mDataUAV2.GetAddressOf(), nullptr);
  40.         md3dImmediateContext->CSSetShaderResources(0, 1, mDataSRV1.GetAddressOf());
  41.         md3dImmediateContext->Dispatch(matrixWidth / TRANSPOSE_BLOCK_SIZE, 
  42.             matrixHeight / TRANSPOSE_BLOCK_SIZE, 1);
  44.         // 对Buffer2排序列数据
  45.         md3dImmediateContext->CSSetShader(mBitonicSort_CS.Get(), nullptr, 0);
  46.         md3dImmediateContext->Dispatch(size / BITONIC_BLOCK_SIZE, 1, 1);
  48.         // 接着转置回来，并把数据输出到Buffer1
  49.         SetConstants(matrixWidth, level, matrixWidth, matrixHeight);
  50.         md3dImmediateContext->CSSetShader(mMatrixTranspose_CS.Get(), nullptr, 0);
  51.         md3dImmediateContext->CSSetShaderResources(0, 1, pNullSRV.GetAddressOf());
  52.         md3dImmediateContext->CSSetUnorderedAccessViews(0, 1, mDataUAV1.GetAddressOf(), nullptr);
  53.         md3dImmediateContext->CSSetShaderResources(0, 1, mDataSRV2.GetAddressOf());
  54.         md3dImmediateContext->Dispatch(matrixWidth / TRANSPOSE_BLOCK_SIZE,
  55.             matrixHeight / TRANSPOSE_BLOCK_SIZE, 1);
  57.         // 对Buffer1排序剩余行数据
  58.         md3dImmediateContext->CSSetShader(mBitonicSort_CS.Get(), nullptr, 0);
  59.         md3dImmediateContext->Dispatch(size / BITONIC_BLOCK_SIZE, 1, 1);
  60.     }
  61. }

最后是std::sort和双调排序的比较结果：

可以初步看到双调排序的排序用时比较稳定，而快速排序明显随元素数目增长而变慢。

DirectX11 With Windows SDK完整目录

Github项目源码

欢迎加入QQ群: 727623616 可以一起探讨DX11，以及有什么问题也可以在这里汇报。

原文链接：http://www.cnblogs.com/X-Jun/p/10398953.html

 友情链接：直通硅谷 　点职佳 　北美留学生论坛

游戏设计热门文章

  • DirectX11--深入理解与使用2D纹理资源
  • unity渲染篇：烘焙模型贴图
  • Unity导入模型出现 (Avatar Rig Configuration mis-match. Bone length in configuration does not match position in animation)?
  • Unreal: Dynamic load map from Pak file
  • 《unity 3D 游戏开发 第二版》宣雨松 分享 pdf下载
  • 空间划分的数据结构(网格/四叉树/八叉树/BSP树/k-d树/BVH/自定义划分)
  • Unity编辑器汉化(中文语言包)
  • [Unity编辑器扩展基础总结] 第3章 编辑器下的数据保存
  • Unity 3D游戏开发 pdf高清下载
  • 用C#写一个俄罗斯方块

    • 游戏设计推荐文章

  • Unity3D开发入门教程（二）—— Lua入门
  • Unity3D开发入门教程（三）——添加启动脚本
  • Unity3D开发入门教程（四）——用Lua实现组件
  • RectMask2D裁剪Canvas无效问题
  • Python编程环境设置
  • Minecraft类游戏地形生成机制
  • 3D网页小实验-基于Babylon.js与recast.js实现RTS式单位控制
  • Unity3D OpenVR 虚拟现实 保龄球打砖块游戏开发
  • [Unity编辑器扩展基础总结] 第3章 编辑器下的数据保存
  • 关于看门狗的两种模型以及带来的思考

    • 本站QQ群：前端 618073944 | Java 606181507 | Python 626812652 | C/C++ 612253063 | 微信 634508462 | 苹果 692586424 | C#/.net 182808419 | PHP 305140648 | 运维 608723728

    W3xue 的所有内容仅供测试，对任何法律问题及风险不承担任何责任。通过使用本站内容随之而来的风险与本站无关。
    关于我们  |  意见建议  |  捐助我们  |  报错有奖  |  广告合作、友情链接（目前9元/月）请联系QQ：27243702 沸活量
    皖ICP备17017327号-2　皖公网安备34020702000426号